Introduction

This article illustrates an analysis of the President George W. Bush’s job approval from January 2001 through Sep 2004 with disposable income excluded from the statistical model. Presidents with a job approval rating of less than 50 percent are unlikely to be re-elected. During June, Bush’s job approval rating averaged 47 percent in five major polls.[1]

Observations

We note immediately the unusual, roller-coaster characteristic of the Bush Presidency, divided into several distinct phases (See Figure 1). A first phase, lasting through September 10, 2001, resembles the course of many other presidencies: approval begins to decline soon after the inauguration, although it may respond to short-term events and the presidents’ policy successes and failures, especially on economic issues. The second phase began on September 11, 2001. In the aftermath of the attacks in New York and Washington, Bush’s approval surged to the highest level ever recorded, and well into 2002, it remained above the average for his entire term. This was the largest and longest “rally” in presidential approval that has ever been recorded. A third phase of the Bush Presidency began with the war in Iraq when his slowly declining approval from September 11th surged once again after the war began (although not to the levels of fall 2001). After the end of major hostilities on May 1, 2003, approval began a long decline to the 47 percent level cited immediately above.[2]

Figure 1. Time Series of the Presidential Job Approval Ratings for George W. Bush

Since we are only looking at job approval rating, we will exclude the third phase, for we do not know how much of the decline in the post-Iraq war phase was due to the unpopularity of the war and occupation, and in particular to the casualties that were been suffered. This is quite different than an emergency response to an attack on our country on 9/11.

The President’s Job Approval Rating takes account of citizen policy evaluations beyond the single issue of the War with Iraq. We consider here the external factors: (1) Executive Response to the World Trade Center terrorist attack, (2) disposable personal income growth per capita (RDPI), and (3) a dummy variable reflecting a change on September 9, 2001.

The data can be downloaded in Excel format (then saves as .CSV) from:

 http://www.owlnet.rice.edu/~stoll/bushpop/fpc.xls.

Intervention

Suppose we wanted to analyze the impact of a change in policy. Policy changes are often used to intervene in some state of distress, such as recession, natural disaster, foreign policy, and so on. In this time series analysis, the intervention came in the form of President Bush’s response to the World Trade Center attacks on September 11, 2001. A second, but one with less impact, was the President’s decision to invade Iraq in 2003. We can see both of these in the time series plot below.

Selecting a Model Functional Form

We do not go into great detail here on selecting the appropriate model function form; however, the complete code for performing this analysis is included in the appendix. We used SAS Studio (University Edition) to perform our analysis. The University Edition can be download and used for personal training, even if you are not a student or faculty. However, we cannot use this version of SAS Studio for professional work. To access SAS Studio and set up an account, go to:

<http://www.sas.com/en_us/software/university-edition.html>

Selecting a functional for is best performed by using PROC TIMESERIES to decompose the time series into its components and creating diagnostic plots. For example, by looking at the autocorrelation function (ACF) and partial autocorrelation (PACF) plots of the differenced series, you can tentatively identify the numbers of AR and/or MA terms that are needed.[3]

Model Development and Analysis

The time series models used in this analysis were an ARIMA(0,1,0) model and UCM models. As discussed in a previous post, ARIMA interactively applies Auto-Regressive and Moving Average component, along with a dependent lag. For this model, however, only a dependent lag is used, for instance, ARIMA(AR=0, Dep. Lag=1, MA=0).

The UCM procedure analyzes and forecasts equally spaced univariate time series data by using an unobserved components model (UCM). As we discussed in a previous post, UCMs are also called structural models in the time series literature.

The predictors used in these models included the RDPI as previously mentioned and a dummy variable for the event/date September 11, 2001. The intervention in this time series in the Executive Response to the terrorist attacks on the World Trade Center. We are not considering the second intervention, the Executive decision to invade Iraq.

To help determine the actual value of the external predictor variable WTC, we construct a contribution chart. The basic idea of a contribution chart is to simply plot the model’s conditional forecasts where certain independent variables take on their true value while others are held equal to their sample means. This allows the modeler to understand the substantive impact that collections of variables “contribute” to the explanatory power of the model.

where y_t is the dependent variable, y_t-1 is the dependent lagged variable, φ is the coefficient of the dependent lag,  x_t is the independent variable with coefficient β and  ε_t is the error term.

The simplest example of a contribution chart involves one explanatory variable with on the lagged dependent variable (LDV). In this instance, the lagged dependent variable functions as a feedback loop, and the coefficient on the LDV defines the magnitude of this amplification. So, a naïve way of constructing the contribution chart is to simply plot the contemporaneous contribution of the independent variable, magnified by the geometric factor implied by the LDV.

where  are estimates of their associated parameters.

This is the most straightforward approach but assumes all amplification is instantaneous, which is not the case. This naïve approach can be easily implemented in a spreadsheet, using the forecasted data generated by the model, e.g. PROC LOGISTIC in SAS Studio.

Contribution Chart

The contribution of WTC toward the Presidential Job Approval Ratings is shown in Figure 2. This intervention event clearly had an impact on President Bush’s job approval ratings. Though the intervention ended about 23 December 2001, the contribution chart depicts the forecasted contribution as well. So, WTC continues to have an impact after it has officially ended.

Figure 2. Contribution of WTC toward the Presidential Job Approval Ratings

UCM Model Parameters

The model parameters for the independent variable (see Table 1) and the dependent lag coefficients (see Table 1), and the Level (see Table 2 for the intercept component) are required for implementing Equation 1.

Table 1. Model parameters for the independent variables

Table 2. Trend Information for Final UCM Model

Excel Cell Formulas

The Excel formulas representing Equation 1 are shown in Table 3.

Table 3. Excel formulas for the contribution calculations

The Art of Modeling

We did not include SEP11 in the model, even though it is significant since the two independent variables SEP11 and WTC are highly correlated, and the effects are captured by WTC. The contribution chart including all three independent variables reveals why RDPI is not significant as it contributes very little to the Job Approval Ratings.

Figure 3. Contribution chart with all three independent variables

Conclusion

Contribution graphs in time series analysis is an excellent way to understand how significant predictor variables impact the dependent variable as demonstrated by WTC for the Presidential Job Approval Ratings.

APPENDIX – Code

/* Generated Code (IMPORT) */
/* Source File: bushjob.csv */
/* Source Path: /home/jeff47/sasuser.v94 */
/* Code generated on: Tuesday, April 5, 2016 6:30:28 PM */
/* Upload dataset file */
FILENAME REFFILE "/home/jeff47/sasuser.v94/bushjob.csv" TERMSTR=CR;
/* Import dataset */
PROC IMPORT DATAFILE=REFFILE
DBMS=CSV
OUT=WORK.BUSH;
GETNAMES=YES;
RUN;
/* View dataset contents */
PROC CONTENTS DATA=WORK.BUSH; RUN;
/* Analyze time series data */
/* Used to determine functional for of the time series model */
PROC TIMESERIES DATA=bush
PLOTS = (series cycles acf pacf decomp)
CROSSPLOTS=ALL
out=series
outtrend=trend
outseason=season print=(seasons decomp);
ID date interval=week accumulate=avg;
VAR approve;
CROSSVAR wtc rdpi sep11;
RUN;
/* Plot trend statistics */
title1 "Trend Statistics";
PROC SGPLOT data=trend;
series x=date y=max  / lineattrs=(pattern=solid);
series x=date y=mean / lineattrs=(pattern=solid);
series x=date y=min  / lineattrs=(pattern=solid);
yaxis display=(nolabel);
format date WEEKDATX23.;
RUN;
/* Write trend dataset */
DATA trend;
set trend;
week = week(date);
RUN;
/* Plot trend by year */
title1 "Trend Statistics by Year";
PROC SGPLOT data=trend;
series x=_season_ y=mean / group=week lineattrs=(pattern=solid);
xaxis values=(1 to 52 by 4);
RUN;
/* Plot seasonal statistics */
title1 "Seasonal Statistics";
PROC SGPLOT data=season;
series x=_season_ y=max  / lineattrs=(pattern=solid);
series x=_season_ y=mean / lineattrs=(pattern=solid);
series x=_season_ y=min  / lineattrs=(pattern=solid);
yaxis display = (nolabel);
xaxis values = (1 to 52 by 4);
RUN;
/* Fit an ARIMA model */
PROC ARIMA data = bush plots = all;
identify var = approve(1) crosscorr=(wtc rdpi sep11);
estimate input = (wtc rdpi sep11);
forecast lead = 52;
RUN;
/* Fit an UCM model with WTC RDPI SEP11*/
PROC UCM DATA=bush;
id date interval=week;
model approve = wtc rdpi sep11;
deplag lags=1;
irregular plot=smooth sp=0 sq=0;
level plot=smooth variance=0 noest;
slope plot=smooth variance=0 noest;
season plot=smooth variance=0 noest type=dummy length=23 print=smooth;
cycle plot=smooth period=3 rho=0.9 print=smooth variance=0 noest=period noest=rho;
estimate plot=panel plot=(all);
forecast plot=decomp print=forecasts lead=52 alpha=0.1 outfor=lbushoan_forecast;
RUN;
/* Fit an UCM model with WTC only*/
PROC UCM DATA=bush;
id date interval=week;
model approve = wtc ;
deplag lags=1;
irregular plot=smooth sp=0 sq=0;
level plot=smooth variance=0 noest;
slope plot=smooth variance=0 noest;
season plot=smooth variance=0 noest type=dummy length=23 print=smooth;
cycle plot=smooth period=3 rho=0.9 print=smooth variance=0 noest=period noest=rho;
estimate plot=panel plot=(all);
forecast plot=decomp print=forecasts lead=52 alpha=0.1 outfor=lbushoan_forecast;
RUN;
/* Fit an model for WTC to get forecast for contribution chart*/
PROC UCM DATA=bush;
id date interval=week;
model wtc = ;
deplag lags=1;
irregular plot=smooth sp=0 sq=0;
level plot=smooth variance=0 noest;
slope plot=smooth variance=0 noest;
season plot=smooth variance=0 noest type=dummy length=23 print=smooth;
cycle plot=smooth period=3 rho=0.9 print=smooth variance=0 noest=period noest=rho;
estimate plot=panel plot=(all);
forecast plot=decomp print=forecasts lead=52 alpha=0.1 outfor=lbushoan_forecast;
RUN;

Works Cited

1. Eichenberg, R.C. and Stoll, R.J. “The Political Fortunes of War: Iraq and the Domestic Standing of President George W. Bush”. Accessed 10-8-2015. http://www.owlnet.rice.edu/~stoll/bushpop/
2. Strickland, J.S. (2016). Time Series Analysis Using Open Source Tools. Glass Tree.
3. Nau, R. (2016). “Identifying the numbers of AR or MA terms in an ARIMA model”. Accessed 11-17-2015. http://people.duke.edu/~rnau/411arim3.htm

Authored by:
Jeffrey Strickland, Ph.D.

Jeffrey Strickland, Ph.D., is the Author of Predictive Analytics Using R and a Senior Analytics Scientist with Clarity Solution Group. He has performed predictive modeling, simulation and analysis for the Department of Defense, NASA, the Missile Defense Agency, and the Financial and Insurance Industries for over 20 years. Jeff is a Certified Modeling and Simulation professional (CMSP) and an Associate Systems Engineering Professional (ASEP). He has published nearly 200 blogs on LinkedIn, is also a frequently invited guest speaker and the author of 20 books including:

• Operations Research using Open-Source Tools
• Discrete Event simulation using ExtendSim
• Crime Analysis and Mapping
• Missile Flight Simulation
• Mathematical Modeling of Warfare and Combat Phenomenon
• Predictive Modeling and Analytics
• Using Math to Defeat the Enemy
• Verification and Validation for Modeling and Simulation
• Simulation Conceptual Modeling
• System Engineering Process and Practices

Connect with Jeffrey Strickland
Contact Jeffrey Strickland